Derivatives, Section 2.1, page 120
Problem 51
Does the parabola have a tangent line whose slope is -1? If so, find an equation for this line. If not, why not?
Since the derivative of a quadratic function is linear, we know that there is a point on the parabola with slope -1, so we set about finding it:
> | y:=2*x^2-13*x+5; |
> | solve(diff(y,x)=-1,x); |
So the parabola has slope -1 when x=3. Now we can find the equation of the tangent line and graph - note the use of the "tangent line idiom":
> | tanline:=subs(x=3,y)+subs(x=3,diff(y,x))*(x-3); |
> | plot({y,tanline},x=-1..6,color=blue,thickness=2); |
Problem 60 Graph and on the same screen graph for h = 2, 1, 0.2. Explain what is going on.
We'll graph thicker than the others so we can get see what's happening:
> | f:=3*x^2; |
> | f1:=((x+h)^3-x^3)/h; |
> | with(plots,display): |
> | A:=plot(f,x=-2..2,-0.1..3,thickness=4,color=blue): |
> | B:=plot({subs(h=2,f1),subs(h=1,f1),subs(h=0.2,f1)},x=-2..2, -0.1..3,thickness=2,color=red): |
> | display({A,B}); |
As h gets smaller the graphs of f1 approach that of f - as to be expected since the difference quotient in f1 is approaching the derivative of , which is f= .
From the other side:
> | C:=plot({subs(h=-2,f1),subs(h=-1,f1),subs(h=-0.2,f1)},x=-2..2,-0.1..3,thickness=2,color=red): |
> | display({A,C}); |
Section 2.2, page 129, Problem 24
Find the derivative of . ..
This is routine.
> | diff((5*x+1)/(2*sqrt(x)),x); |
> | simplify(%); |
Problem 43
Find the tangents to at the points (0,0) and (1,2).
We'll use the "tangent line idiom" from before:
> | y:=4*x/(x^2+1); |
> | tanline0:=subs(x=0,y)+subs(x=0,diff(y,x))*(x-0); |
> | tanline1:=subs(x=1,y)+subs(x=1,diff(y,x))*(x-1); |
Note that this second tangent line is horizontal. Now we can plot the curve and the two tangent lines:
> | plot({y,tanline0,tanline1},x=-4..4,-4..4,thickness=2,color=blue); |
Section 2.3, page 140, Problem 13
A 45-caliber bullet fired straight up from the surface of the moon would reach a height of feet after t seconds. On Earth, in the absence of air its htight would be feet after t seconds. How long will the bullet be aloft in each case? How high would the bullet go?
We define the functions for the bullets on the moon and the earth:
> | moon:=832*t-2.6*t^2; earth:=832*t-16*t^2; |
To find how long the bullets are in the air, solve for when their heights (these functions) are zero (of course, t=0 is an extraneous solution):
> | solve(moon=0,t); solve(earth=0,t); |
So the lunar bullet is in the air for 320 seconds, and the terran one for 52 seconds.
To find the maximum height, set the derivative (velocity) equal to zero for the time, then plug into the height expression:
> | subs(t=solve(diff(moon,t)=0,t),moon); |
> | subs(t=solve(diff(earth,t)=0,t),earth); |
So the lunar bullet goes 66,560 feet up from the surface, and the terran bullet goes up only 10,816 feet.
Section 2.4, page 152, Problem 43
Compute as .
A quick limit problem for Maple:
> | Limit(sin(1-cos(t))/(1-cos(t)),t=0)=limit(sin(1-cos(t))/(1-cos(t)),t=0); |
Problem 54
Does the graph of have any horizontal tanents in the interval ? If so, where? If not, why not.?
> | y:=2*x+sin(x); |
The graph will have a horizontal tangent exactly where the derivative of this function is equal to zero. Thus, we need to solve for where the derivative is equal to zero.
> | solve(diff(y,x)=0,x); |
We have a little problem here, since arccos(2) does not exist (as a real number, at least). Just for the record, the derivative of y is
> | diff(y,x); |
so we can see why this expression will never be equal to zero. In particular, this tells us that the tangent line will never be horizontal. We can now graph the function and see that this is indeed the case.
> | plot(y,x=0..2*Pi,color=blue,thickness=2); |
Section 2.5, page 160
Problems 27 and 42.
Find the derivative of both and .
These are easy with Maple:
> | diff(1/21*(3*x-2)^7+1/(4-1/(2*x^2)),x); |
> | diff((1+cot(t/2))^(-2),t); |
> | simplify(%); |
Section 2.6, page 170, Problem 42
If
, use implicit differentiation to compute
and then
.
To do implicit derivatives, you have to be careful to let Maple know that you are thinking of y as a function of x (by writing y(x)):
> | restart; |
> | eqn:=x*y(x)+y(x)^2=1; |
> | diff(eqn,x); |
So Maple can take the derivative of both sides of an equation. To get the first and second derivatives of y, we have to solve this equation (and its derivative) for y' and y'':
> | yprime:=solve(diff(eqn,x),diff(y(x),x)); |
Now we can take the derivative of y' to get y'':
> | ypp:=simplify(subs(diff(y(x),x)=yprime,diff(yprime,x))); |
Section 2.7, page 179, Problem 32
You are videotaping a car race from a stand 132 feet from the track. Your camera is focussing on a car that is moving at 180 mph (264 ft/sec). How fast will your camera's angle be changing when the car is exactly in front of you? A half second later?
Let us call the distance from the car to the point on the track directly in front of you x. Thus, we know that feet per second, and . We're thinking of both x and as functions of t, so we can write:
> | eqn:=tan(theta(t))=x(t)/132; |
We want to compute d /dt at the moment when x=0, and a half second later (when we will
have x=132 feet).
We differentiate both sides of the second equation above and get
> | diff(eqn,t); |
We need to solve this for d /dt --
> | thetaprime:=solve(diff(eqn,t),diff(theta(t),t)); |
But we know that , so we can substitute that into what we just calculated:
> | thetaprime:=subs(tan(theta(t))=x(t)/132,thetaprime); |
Now we can calculate the derivatives we need:
> | subs(diff(x(t),t)=264,x(t)=0,thetaprime); |
> | subs(diff(x(t),t)=264,x(t)=132,thetaprime); |
So the camera angle is changing at a rate of 2 radians/sec when the car is in front of us, and at a rate of 1 radian per second a half-second later.